# 25 (высокий уровень, время – 30 мин)

**Тема**: Обработка массива (написать программу из 10-15 строк на языке программирования или алгоритм на естественном языке).

**Что нужно знать**:

* *массив* – это набор однотипных элементов, имеющих общее имя и расположенных в памяти рядом
* для обращения к элементу массива используют квадратные скобки, запись **A[i]** обозначает элемент массива **A** с номером (индексом) **i**
* для обработки всех элементов массива используется цикл вида[[1]](#footnote-1)

**for i:=1 to N do begin**

 **{ что-то делаем с элементом A[i] }**

**end;**

переменная **i** обозначает номер текущего элемента массива, она меняется от 1 до N с шагом 1, то есть мы **″**проходим**″** последовательно все элементы

* *матрица* (двухмерный массив) – это прямоугольная таблица однотипных элементов
* если матрица имеет имя **A**, то обращение **A[i,k]** обозначает элемент, расположенный на пересечении строки **i** и столбца **k**

|  |  |  |  |
| --- | --- | --- | --- |
|  |  | **k** |  |
|  |  |  |  |
|  |  |  |  |
| **i** |  | **A[i,k]** |  |
|  |  |  |  |

* каждая строка матрицы – это обычный (одномерный, линейный) массив**;** для того, чтобы обработать строку **i** в матрице из **M** столбцов, нужно использовать цикл, в котором меняется номер столбца **k**:

**for k:=1 to M do begin**

 **{ что-то делаем с элементом A[i,k] }**

**end;**

* каждый столбец матрицы – это обычный (одномерный, линейный) массив**;** для того, чтобы обработать столбец **k** в матрице из **N** строк, нужно использовать цикл, в котором изменяется номер строки **i**:

**for i:=1 to N do begin**

 **{ что-то делаем с элементом A[i,k] }**

**end;**

* условие задачи записано на нескольких языках (алгоритмический язык, Паскаль, Бейсик и Си)**;** в принципе, решение можно писать и на любом другом языке, в том числе на естественном языке или в виде блок-схемы.

### Пример задания:

**Р-04**. *Дан целочисленный массив из 20 элементов. Элементы массива могут принимать целые значения от –10 000 до 10 000 включительно. Опишите на естественном языке или на одном из языков программирования алгоритм, позволяющий найти и вывести количество пар элементов массива, сумма которых нечётна и положительна. Под парой подразумевается два подряд идущих элемента массива.*

*Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но использовать все описанные переменные не обязательно.*

|  |  |
| --- | --- |
| Паскаль | Алгоритмический язык |
| **const N = 20;** **var a: array [1..N] of integer;**  **i, j, k: integer;** **begin** **for i := 1 to N do** **readln(a[i]);**  **...****end.** | алгнач цел N = 20 цел таб a[1:N] цел i, j, k нц для i от 1 до N ввод a[i] кц ...кон |

**Решение:**

1. даже если вы хорошо владеете программированием, сначала лучше (прежде всего, для себя) написать алгоритм на русском языке
2. в задании нужно перебрать все пары соседних элементов, начиная от пары (a[1], a[2]) до пары (a[N-1],a[N]) и подсчитать, для скольких пар сумма элементов нечётна и положительна
3. поскольку нам нужно что-то считать, придётся использовать переменную счётчик**;** сначала её значение равно 0, затем, при каждой найденной подходящей паре, значение счётчика увеличивается на 1**;** в качестве счётчика можно использовать любую целую переменную из тех, что были объявлены в условии, например, k:

**k := 0;**

**перебрать все пары**

 **если пара подходящая, то**

 **k := k + 1**

1. как же перебрать все пары? примем, что переменная i будет хранить номер первого элемента в паре, то есть, будем рассматривать пары (a[i],a[i+1])
2. очевидно, что нужно организовать цикл, который перебирает все значения i в интервале от 1 (для первой пары, (a[1], a[2])) до N-1 (для последней пары, (a[N-1],a[N]))

**for i:=1 to N-1 do ...**

1. как определить, что пара (a[i],a[i+1]) подходящая? нужно вычислить её сумму a[i]+a[i+1] и проверить, верно ли, что эта сумма нечётна и положительна
2. нечётность проверим, вычислив остаток от деления на 2**;** если этот остаток не равен 0, число нечётное
3. получается такой цикл, после которого нужно не забыть вывести результат – значение счётчика k:

**k := 0;**

**for i:=1 to N-1 do**

 **if (a[i]+a[i+1] > 0) and ((a[i]+a[i+1]) mod 2 <> 0) then**

 **k := k + 1;**

**writeln(k);**

1. для того, чтобы не вычислять дважды сумму в условном операторе, можно было записать её в свободную переменную j:

**k := 0;**

**for i:=1 to N-1 do begin**

 **j := a[i]+a[i+1];**

 **if (j > 0) and (j mod 2 <> 0) then**

 **k := k + 1**

**end;**

**writeln(k);**

1. возможен и ответ на естественном языке (русском):

**Записать значение 0 в переменную** k**. Затем в цикле перебрать все пары соседних элементов, начиная с пары (a[1],a[2]) до пары (a[N-1],a[N]). Для каждой пары вычислить сумму, если эта сумма положительна и нечётна (остаток от её деления на 2 не равен нулю), увеличить значение k на единицу. После завершения цикла вывести значение k.**

|  |
| --- |
| **Возможные проблемы**:* + не забудьте сказать, что нужно вывести после окончания работы программы
	+ не забудьте задать правильное начальное значение для счётчика
	+ не забудьте, что в Паскале каждое из простых условий (отношений) нужно брать в скобки
	+ не забудьте, что если в теле цикла нужно выполнить несколько операторов, их нужно заключать в **″**операторные скобки**″** begin-end
	+ цикл по i должен заканчиваться не на N, а на N-1, чтобы не было выхода за границы массива (рассматриваются элементы a[i] и a[i+1])
	+ если вы достаточно хорошо владеете русским языком для того, чтобы понятно излагать свои мысли, с точки зрения тактики рекомендуется писать алгоритм на русском языке – по крайней мере, тут не снизят балл за пропущенную точку с запятой
	+ просмотрите внимательно диапазон, в котором находятся исходные числа**;** дело в том, что во многих языках, например, в Паскале и в Си, остаток от деления отрицательного числа на положительное – число отрицательное, например (-7) mod 2 = -1, поэтому определять, например, **″**неделимость**″** элемента массива на 2 с помощью условия **a[i]** **mod** **2** **=** **1** нельзя (не будет работать для отрицательных чисел), нужно использовать условие

**a[i]** **mod** **2** <> **0.** |

### Ещё пример задания:

**Р-03**. *Дан целочисленный массив из 20 элементов. Элементы массива могут принимать целые значения от 0 до 1000. Опишите на русском языке или на одном из языков программирования алгоритм, позволяющий найти и вывести минимальное значение среди элементов массива, которые имеют чётное значение и не делятся на три. Гарантируется, что в исходном массиве есть хотя бы один элемент, значение которого чётно и не кратно трем.*

*Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но использовать все описанные переменные не обязательно.*

***Естественный язык:***

**Объявляем массив A из 20 элементов.**

**Объявляем целочисленные переменные I, J, MIN.**

**В цикле от 1 до 20 вводим элементы массива A с 1-го по 20-й.**

***Паскаль:***

**const N=20;**

**var a: array [1..N] of integer;**

 **i, j, min: integer;**

**begin**

 **for i:=1 to N do**

 **readln(a[i]);**

 **…**

**end.**

**Решение:**

1. даже если вы хорошо владеете программированием, сначала лучше (прежде всего, для себя) написать алгоритм на русском языке
2. здесь требуется найти минимальный элемент из всех, которые имеют чётное значение и не делятся на 3
3. делимость одного целого числа на другое проверяется с помощью операции взятия остатка (в Паскале – операция mod): первое число делится на второе, если остаток от деления равен 0
4. тогда условие, определяющее отбор нужных элементов, запишется в виде

(a[i] mod 2 = 0) and (a[i] mod 3 <> 0)

1. стандартный цикл поиска минимального элемента, удовлетворяющего условию, выглядит так:

**for i:=1 to N do**

 **if <условие верно> and (a[i] < min) then**

 **min := a[i];**

1. остается один вопрос: каким должно быть начальное значение переменной min? его нужно выбрать таким, чтобы для первого же **″**подходящего**″** элемента выполнилось условие a[i] < min, и это **″**временное**″** начальное значение было бы заменено на реальное
2. к счастью, диапазон входных чисел ограничен (от 0 до 1000), поэтому можно выбрать любое значение, больше 1000, например, 1001 или 9999[[2]](#footnote-2)
3. таким образом, решение задачи на естественном языке выглядит так:

*Записываем в переменную* min *значение 1001.
Затем в цикле просматриваем все элементы массива, с первого до последнего. Если остаток от деления очередного элемента на 2 равен 0 и остаток от его деления на 3 не равен нулю и значение элемента меньше, чем значение переменной* min*, записать в переменную* min *значение рассматриваемого элемента массива. Затем переходим к следующему элементу.
После окончания работы цикла выводим значение переменной* min*.*

1. аналогичное решение на Паскале:

**min:=1001;**

**for i:=1 to N do**

**if (a[i] mod 2=0) and (a[i] mod 3 <> 0) and (a[i]<min) then**

 **min:=a[i];**

**writeln(min);**

|  |
| --- |
| **Возможные проблемы**:* + не забудьте сказать, что нужно вывести после окончания работы программы
	+ если вы достаточно хорошо владеете русским языком для того, чтобы понятно излагать свои мысли, с точки зрения тактики рекомендуется писать алгоритм на русском языке – по крайней мере, тут не снизят за пропущенную точку с запятой
	+ просмотрите внимательно диапазон, в котором находятся исходные числа**;** дело в том, что во многих языках, например, в Паскале и в Си, остаток от деления отрицательного числа на положительное – число отрицательное, например (-7) mod 3 = -1, поэтому определять, например, **″**неделимость**″** элемента массива на 3 с помощью условия **a[i]** **mod** **3** **=** **1** нельзя (не будет работать для отрицательных чисел), нужно использовать условие

**a[i]** **mod** **3** <> **0.** |

### Ещё пример задания:

**Р-02**. *Опишите на русском языке или одном из языков программирования алгоритм получения из заданного целочисленного массива размером 30 элементов другого массива, который будет содержать модули значений элементов первого массива (не используя специальной функции, вычисляющей модуль числа). Полученный массив нужно вывести на экран.*

**Решение:**

1. даже если вы хорошо владеете программированием, сначала лучше (прежде всего, для себя) написать алгоритм на русском языке (или на псевдокоде – это нечто среднее между словесным алгоритмом и готовой программой)
2. по условию нужно выделить в памяти два массива одинакового размера, назовем их **A** и **B;** обозначим размер массивов через **N**, индексы элементов изменяются от 1 до **N;**
3. в цикле в каждый элемент **B[i]** массива **B** нужно записать модуль соответствующего элемента **A[i]** массива **A**, это нужно сделать для всех **i** от 1 до **N**
4. есть небольшая сложность: запрещено использовать стандартную функцию вычисления модуля**;** согласно определению модуля решение может быть такое: если элемент **A[i]** больше или равен нулю, записываем в **B[i]** его значение без изменений, а если меньше нуля – меняем знак, то есть, в **B[i]** записываем (**-A[i]**)
5. решение в виде алгоритма на русском языке может выглядеть так:
**″**Выделяем в памяти второй массив того же размера. В цикле рассматриваем все элементы первого массива с первого до последнего. Если текущий элемент больше нуля или равен нулю, в соответствующий элемент второго массива записываем его значение без изменений**;** если текущий элемент меньше нуля, во второй массив записываем значение элемента с обратным знаком. Выводим второй массив на экран**″**.
6. осталось написать программу, практически дословно реализующую это решение:

**const N = 30;**

**var a, b:array[1..N] of integer;**

 **i: integer;**

**begin**

**for i:=1 to N do { ввод всех элементов массива с клавиатуры }**

 **read(a[i]);**

**for i:=1 to N do { формирование массива B }**

 **if a[i] < 0 then**

 **b[i]:= -a[i]**

 **else b[i]:= a[i];**

**writeln('Результат:');**

**for i:=1 to N do { вывод всех элементов массива B }**

 **write(b[i], ' ');**

**end.**

1. размер массива грамотно задавать через константу (**const N = 30;** ), а не вписывать число в каждый цикл**;** тогда, если нужно будет переделать программу для массива другого размера, достаточно будет изменить всего одно число в начале программы

|  |
| --- |
| **Возможные проблемы**:* + проверяйте правильность минимального и максимального значения переменной цикла в заголовке цикла **for**
	+ не забывайте вывести результат в конце работы программы
 |

### Еще пример задания:

**Р-01**. *Опишите на русском языке или одном из языков программирования алгоритм подсчета максимального количества подряд идущих совпадающих элементов в целочисленном массиве длины 30.*

**Решение:**

1. сначала нужно понять задачу**;** предположим, что в массиве есть одинаковые элементы, стоящие рядом:

|  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
| **1** | **1** | **2** | **2** | **1** | **1** | **1** | **1** | **3** | **3** | **2** | **2** |

1. самая длинная цепочка стоящих рядом элементов в данном случае состоит из 4-х единиц (она выделена желтым фоном)
2. нам нужно по крайней мере две переменных: для хранения номера текущего элемента (при обработке массива в цикле) и для хранения максимального количества идущих подряд элементов (обозначим ее **kMax**)
3. в целом (пока неточный) алгоритм может выглядеть так: **″**пройти весь массив, подсчитывая для каждого элемента длину цепочки подряд идущих одинаковых чисел, если эта длина больше **kMax**, то записать ее в **kMax″**
4. отсюда сразу следует, что необходима еще одна переменная (обозначим ее через **k**), показывающая для каждого элемента массива длину цепочки одинаковых чисел, которая заканчивается на этом элементе:

|  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  | **1** | **1** | **2** | **2** | **1** | **1** | **1** | **1** | **3** | **3** | **2** | **2** |
| **k** | 1 | 2 | 1 | 2 | 1 | 2 | 3 | 4 | 1 | 2 | 1 | 2 |
| **kMax** | 1 | 2 | 2 | 2 | 2 | 2 | 3 | 4 | 4 | 4 | 4 | 4 |

1. следующий шаг к решению: нужно понять, как изменять переменную **k** при проходе по массиву**;** можно сделать так: если очередной элемент равен предыдущему, счетчик **k** увеличиваем на единицу, а если не равен – записываем в него 1 (цепочка одинаковых чисел кончилась, началась новая, в ней пока один элемент)
2. при таком подходе проблема может возникнуть при просмотре первого элемента, потому что для него нет предыдущего**;** поэтому описанную выше процедуру будем в цикле применять ко всем элементам массива, начиная **со второго** (а не с первого)**;** в самом начале программы запишем в **k** и **kMax** по единице – таким образом, мы **″**вручную**″** (без цикла) рассмотрели первый элемент массива
3. теперь можно написать алгоритм на русском языке:
**″**Выделим две вспомогательные переменные, **k** и **kMax**, и запишем в каждую из них по единице. В цикле рассматриваем все элементы массива со **второго** до последнего, если очередной элемент равен предыдущему, увеличиваем **k;** если **k > kMax**, записываем в **kMax** значение **k**. В конце цикла в **kMax** окажется требуемое значение**″**.
4. этот алгоритм реализуется в такой программе:

**const N =30;**

**var a: array[1..N] of integer;**

 **i, k, kMax: integer;**

**begin**

**for i:=1 to N do readln(A[i]); { ввод массива }**

**k := 1; { обрабатываем A[1] }**

**kMax := 1;**

**for i:=2 to N do begin { а теперь в цикле A[2]...A[N} }**

 **if A[i] = A[i-1] then { цепочка продолжается }**

 **k := k + 1**

 **else k := 1; { цепочка закончилась }**

 **if k > kMax then kMax := k;**

**end;**

**writeln(kMax);**

**end.**

|  |
| --- |
| **Возможные проблемы**:* + как видим, основная сложность в этой задаче – не написать программу, а придумать хороший (часто еще нужно – быстрый) алгоритм
	+ проверьте, что будет записано в переменные до начала цикла (определены ли их начальные значения)
	+ проверяйте, не выйдет ли индекс за границу массива в начале или в конце цикла
	+ будьте внимательны с **″**крайними**″** случаями, например, нужно обязательно убедиться, что программа работает, когда интересующая нас цепочка стоит в самом начале или в самом конце массива
 |

### Еще пример задания:

**Р-00**. *Дан целочисленный квадратный массив 10 х 10. Опишите на русском языке или на одном из языков программирования алгоритм вычисления суммы максимальных элементов из каждой строки. Напечатать значение этой суммы. Предполагается, что в каждой строке такой элемент единственный.*

**Решение:**

1. суть задачи: среди элементов каждой строки нужно выбрать максимальный, и все эти выбранные значения сложить
2. несложно сразу написать алгоритм на русском языке:
**″**Чтобы накапливать сумму, нужно ввести целую переменную **Sum**, в которую в самом начале записываем 0 **;** далее в цикле просматриваем все строки, для каждой строки находим максимальный элемент и прибавляем его значение к **Sum**. Для определения максимального элемента в строке вводим переменную **max** и сначала записываем в нее значение первого элемента этой строки. Затем в цикле просматриваем все остальные элементы, начиная со **второго** до конца массива. Если очередной элемент больше значения **max**, записываем в **max** значение этого элемента**″**.
3. сначала напишем программу на псевдокоде:

**const N=10;**

**{ ввод матрицы N на N }**

**Sum := 0;**

**for i:=1 to N do begin**

 **{ max := максимальный элемент в i-ой строке }**

 **Sum := Sum + max;**

**end;**

1. остается записать на Паскале те части, которые взяты в фигурные скобки, и до конца оформить программу**;** по правилам ЕГЭ можно не писать в программе команды для ввода массива, поэтому мы оставим на этом месте комментарий:

**const N=10;**

**var A: array[1..N,1..N] of integer;**

 **i, k, max, Sum: integer;**

**begin**

**{ ввод матрицы N на N }**

**Sum := 0;**

**for i:=1 to N do begin**

 **max := A[i,1];**

 **for k:=2 to N do**

 **if A[i,k] > max then max := A[i,k];**

 **Sum := Sum + max;**

**end;**

**writeln(Sum);**

**end.**

|  |
| --- |
| **Возможные проблемы**:* + проверьте, правильно ли заданы (и заданы ли вообще) начальные значения для всех переменных
	+ проверьте, правильно ли расставлены операторные скобки **begin-end**, ограничивающие тело цикла**;** их обязательно нужно ставить, если в теле цикла несколько операторов
	+ проверяйте, не выйдет ли индекс за границу массива в начале или в конце цикла
	+ не перепутайте номер строки (это первый индекс) и номер столбца (второй индекс)
	+ для надежности не рекомендуется использовать в одной программе переменные **i** и **j**, потому что они слишком похоже выглядят, вот пример ошибочного решения в этой задаче:

**for i:=1 to N do begin** **max := A[i,1];**  **for i:=2 to N do** **if A[j,i] > max then max := A[i,j];**  **Sum := Sum + max;** **end;** * + если вы все же используете переменные **i** и **j**, нужно писать их очень четко, чтобы они отличались друг от друга
 |

|  |
| --- |
| **Немного тактики:*** + в этом задании можно написать алгоритм на русском языке, а можно (вместо этого) написать компьютерную программу на одном из языков программирования
	+ если вы хорошо умеете выражать свои мысли по-русски, ~~собаководы~~ эксперты рекомендуют писать **только** алгоритм на русском языке**;** дело в том, что если вы сделаете много ошибок в программе, оценка будет снижена даже при абсолютно правильном алгоритме
	+ если вам сложно изъясняться на родном языке, а легче записать свои мысли на Паскале или Си – пишите программу, но тщательно проверяйте ее на предмет возможных случайных ошибок-опечаток, которые можно сделать просто по невнимательности:
	+ задавайте все начальные значения для переменных
	+ проверяйте правильность написания ключевых слов
	+ если в теле цикла несколько операторов, заключайте их в блок **begin-end** (операторные скобки)
	+ проверяйте начальное и конечное значение переменной цикла
	+ если вы используете циклы while или repeat, проверьте, что переменная цикла изменяется в теле цикла (иначе в программе будет зацикливание, а на ЕГЭ – потерянные баллы)
	+ выводите на экран именно то, что требуется по условию
	+ ставьте точку с запятой в конце операторов
	+ НЕ ставьте точку с запятой перед **else** (Паскаль)
	+ ставьте точку в конце последнего оператора **end** (Паскаль)
 |

|  |
| --- |
| **За что снимают баллы:*** + задано неверное начальное значение переменных (или вообще не задано)
	+ неверно указано условие завершения цикла
	+ **″**забыли**″** изменять переменную цикла в цикле **while** (**repeat**)
	+ перепутаны знаки < и >, логические операции **or** и **and**
	+ неверно расставлены операторные скобки **begin-end**
	+ программа не выводит результат или выводит не то, что спрашивают
	+ синтаксические ошибки (знаки пунктуации – запятые, точки, точки с запятой**;** неверное написание ключевых слов) допускаются в разумных пределах (если они не искажают замысел автора)
 |

# Задачи для тренировки:

1. Опишите на русском языке или одном из языков программирования алгоритм поиска номер первого из двух последовательных элементов в целочисленном массиве из 30 элементов, сумма которых максимальна (если таких пар несколько, то можно выбрать любую из них).
2. Опишите на русском языке или одном из языков программирования алгоритм подсчета числа элементов, равных максимальному, в числовом массиве из 30 элементов.
3. Опишите на русском языке или одном из языков программирования алгоритм поиска трех последовательных элементов, сумма которых максимальна, в числовом массиве из 30 элементов.
4. Дан прямоугольный массив целых положительных чисел 10 х 20. Опишите на русском языке или на одном из языков программирования алгоритм поиска строки с наименьшей суммой элементов. Вывести на печать номер строки и сумму ее элементов. Предполагается, что такая строка единственна.
5. Дан квадратный массив целых положительных чисел 10 х 10. Опишите на русском языке или на одном из языков программирования алгоритм вычисления суммы элементов строки, в которой расположен элемент с максимальным значением. Вывести значение суммы на печать. Предполагается, что такой элемент единственный.
6. Дан целочисленный прямоугольный массив 6x10. Опишите на русском языке или на одном из языков программирования алгоритм вычисления суммы минимальных элементов из каждой строки. Напечатать значение этой суммы. Предполагается, что в каждой строке минимальный элемент единственный.
7. Дан целочисленный массив из 30 элементов. Элементы могут принимать значения от 0 до 100 ­– баллы, полученные на ЕГЭ. Опишите на русском языке или на одном из языков программирования алгоритм, который определяет и выводит средний балл учащихся, сдавших экзамен (получивших оценку более 20 баллов). Гарантируется, что хотя бы один ученик в классе успешно сдал экзамен. Исходные данные объявлены так, как показано ниже. Использовать другие переменные запрещается.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N = 30;** **var A: array[1..N] of integer;**  **i, x, y: integer;**  **s: real;** **begin** **for i:=1 to N do readln(A[i]);**  **...****end.** | Объявляется массив **A** из 30 элементов. Объявляются целочисленные переменные **i**, **x** и **y**, а также вещественная переменная **s**.В цикле от 1 до 30 заполняются все элементы массива **A** с 1-ого по 30-ый.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {** **const int N=30;**  **int A[N];**  **int i, x, y;**  **float s;**  **for (i=0; i<N; i++)** **scanf(″%d″, &A[i]);**  **...****}** |  |

1. Дан целочисленный массив из 30 элементов. Элементы могут принимать значения от 160 до 200 ­– рост учащихся выпускного класса. В баскетбольную команду берут тех, чей рост не менее 180 см. Опишите на русском языке или на одном из языков программирования алгоритм, который определяет и выводит минимальный рост игрока баскетбольной команды. Гарантируется, что хотя бы один ученик играет в баскетбольной команде. Исходные данные объявлены так, как показано ниже. Использовать другие переменные запрещается.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N = 30;** **var A: array[1..N] of integer;**  **i, x, y: integer;** **begin** **for i:=1 to N do readln(A[i]);**  **...****end.** | Объявляется массив **A** из 30 элементов. Объявляются целочисленные переменные **i**, **x** и **y**В цикле от 1 до 30 заполняются все элементы массива **A** с 1-ого по 30-ый.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {** **const int N=30;**  **int A[N];**  **int i, x, y;**  **for (i=0; i<N; i++)** **scanf(″%d″, &A[i]);**  **...****}** |  |

1. Дан целочисленный массив из 31 элемента, в котором записаны значения температуры воздуха в марте. Элементы массива могут принимать значения от (–20) до 20. Опишите на русском языке или на одном из языков программирования алгоритм, который подсчитывает и выводит среднюю температуру по всем дням, когда была оттепель (температура поднималась выше нуля). Гарантируется, что хотя бы один день в марте была оттепель. Исходные данные объявлены так, как показано ниже. Использовать другие переменные запрещается.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N = 31;** **var A: array[1..N] of integer;**  **i, x, y: integer;**  **s: real;** **begin** **for i:=1 to N do readln(A[i]);**  **...****end.** | Объявляется массив **A** из 31 элемента. Объявляются целочисленные переменные **i**, **x** и **y**, а также вещественная переменная **s**.В цикле от 1 до 31 заполняются все элементы массива **A** с 1-ого по 31-ый.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {** **const int N=31;**  **int A[N];**  **int i, x, y;**  **float s;**  **for (i=0; i<N; i++)** **scanf(″%d″, &A[i]);**  **...****}** |  |

1. Дан целочисленный массив из 30 элементов. Элементы массива могут принимать целые значения от 0 до 100 – баллы учащихся выпускного класса за итоговый тест по информатике. Для получения положительной оценки за тест требовалось набрать не менее 20 баллов. Опишите на русском языке или на одном из языков программирования алгоритм, который находит и выводит минимальный балл среди учащихся, получивших за тест положительную оценку. Известно, что в классе хотя бы один учащийся получил за тест положительную оценку. Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но разрешается не использовать часть из них.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N=30;** **var a: array [1..N] of integer;**  **i, j, min: integer;** **begin**  **for i:=1 to N do readln(a[i]);**  **...****end.** | Объявляется массив **A** из 30 элементов. Объявляются целочисленные переменные **i**, j и **min**.В цикле от 1 до 30 заполняются все элементы массива **A** с 1-ого по 30-ый.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {**  **const int N=30;**  **int a[N];**  **int i, j, min;**  **for (i=0; i<N; i++)** **scanf(″%d″, &a[i]);**  **...****}** |  |

В качестве ответа Вам необходимо привести фрагмент программы (или описание алгоритма на естественном языке), который должен находиться на месте многоточия. Вы можете записать решение также на другом языке программирования (укажите название и используемую версию языка программирования, например, *Borland Pascal 7.0*) или в виде блок-схемы. В этом случае вы должны использовать те же самые исходные данные и переменные, какие были предложены в условии (например, в образце, записанном на естественном языке).

1. Опишите на русском языке или на одном из языков программирования алгоритм определения количества положительных элементов квадратной матрицы, превышающих по величине среднее арифметическое всех элементов главной диагонали.
2. Дан целочисленный массив из 30 элементов. Элементы массива могут принимать целые значения от 0 до 100 – баллы учащихся выпускного класса, полученные на экзамене по информатике. Опишите на русском языке или на одном из языков программирования алгоритм, который позволяет найти и вывести количество учащихся, чьи баллы на экзамене выше среднего балла по классу. Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но разрешается не использовать часть из них.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N=30;** **var a: array [1..N] of integer;**  **i, j: integer;**  **s: real;** **begin** **for i:=1 to N do readln(a[i]);**  **...****end.** | Объявляем массив **A** из 30 элементов. Объявляем целочисленные переменные **i**, **j**.Объявляем действительную переменную **s**.В цикле от 1 до 30 вводим элементы массива **A** с 1-го по 30-й.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {** **const int N=30;**  **int a[N];**  **int i, j;**  **float s;**  **for (i=0; i<N; i++)** **scanf(″%d″, &a[i]);**  **...****}** |  |

В качестве ответа вам необходимо привести фрагмент программы (или описание алгоритма на естественном языке), который должен находиться на месте многоточия. Вы можете записать решение также на другом языке программирования (укажите название и используемую версию языка программирования, например, *Borland Pascal 7.0*) или в виде блок-схемы. В этом случае вы должны использовать те же самые исходные данные и переменные, какие были предложены в условии (например, в образце, записанном на естественном языке).

1. Дан целочисленный массив из 30 элементов. Элементы массива могут принимать произвольные целые значения. С клавиатуры вводится целое число **X**. Опишите на русском языке или на одном из языков программирования алгоритм, который находит и выводит наименьший номер элемента, равного X, или сообщение, что такого элемента нет. Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но разрешается не использовать часть из них.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N=30;** **var a: array [1..N] of integer;**  **i, j, x: integer;** **begin** **for i:=1 to N do readln(a[i]);**  **readln(x);**  **...****end.** | Объявляем массив **A** из 30 элементов. Объявляем целочисленные переменные **i**, **j, x**. В цикле от 1 до 30 вводим элементы массива **A** с 1-го по 30-й. Вводим переменную **X**.... |
| Си |  |
| **#include<stdio.h>** **int main(void) {** **const int N=30;** **int a[N];**  **int i, j, x;**  **for (i=0; i<N; i++)** **scanf(″%d″, &a[i]);**  **scanf(″%d″, &x);**  **...****}** |  |

В качестве ответа вам необходимо привести фрагмент программы (или описание алгоритма на естественном языке), который должен находиться на месте многоточия. Вы можете записать решение также на другом языке программирования (укажите название и используемую версию языка программирования, например, *Borland Pascal 7.0*) или в виде блок-схемы. В этом случае вы должны использовать те же самые исходные данные и переменные, какие были предложены в условии (например, в образце, записанном на естественном языке).

1. Дан целочисленный массив из 30 элементов. Элементы массива могут принимать произвольные целые значения. Опишите на русском языке или на одном из языков программирования алгоритм, который находит и выводит второй максимум массива (элемент, который в отсортированном по невозрастанию массиве стоял бы вторым). Исходные данные объявлены так, как показано ниже. Запрещается использовать переменные, не описанные ниже, но разрешается не использовать часть из них.

|  |  |
| --- | --- |
| Паскаль | Естественный язык |
| **const N=30;** **var a: array [1..N] of integer;**  **i, k, max, max2: integer;** **begin** **for i:=1 to N do readln(a[i]);**  **...****end.** | Объявляем массив **A** из 30 элементов. Объявляем целочисленные переменные **i**, **k, max, max2**. В цикле от 1 до 30 вводим элементы массива **A** с 1-го по 30-й. ... |
| Си |  |
| **#include<stdio.h>** **int main(void) {**  **const int N=30;**  **int a[N];**  **int i, k, max, max2;**  **for (i=0; i<N; i++)** **scanf(″%d″, &a[i]);**  **...****}** |  |

В качестве ответа вам необходимо привести фрагмент программы (или описание алгоритма на естественном языке), который должен находиться на месте многоточия. Вы можете записать решение также на другом языке программирования (укажите название и используемую версию языка программирования, например, *Borland Pascal 7.0*) или в виде блок-схемы. В этом случае вы должны использовать те же самые исходные данные и переменные, какие были предложены в условии (например, в образце, записанном на естественном языке).

1. По традиции нумерация элементов массива в Паскале обычно начинается с единицы, далее N обозначает размер массива (количество элементов). [↑](#footnote-ref-1)
2. Вообще говоря, в данной задаче не требуется находить номер минимального элемента, поэтому сначала можно записать в переменную min число 1000 – проверьте, что программа все равно выдаст верное значение. [↑](#footnote-ref-2)